> <script language="VBScript">
> 
> sub SetURL(URL) 
>         On Error Resume Next
>         dim IriaOLE     
>         set IriaOLE = CreateObject("Iria.IriaOLE")
>         if IriaOLE is Nothing then
>                 MsgBox("Iriaが見付かりません。Iriaを一度起動して下さい。")
>         else
>                 IriaOLE.SetURL URL
>         end if
> end sub
> sub OnIEMenuExt()
>         dim objEvent
>         dim objEventElement
>         dim objSrcAnchor
>         dim objSrcImage
>         set objEvent = external.menuArguments.event
>         set objEventElement = external.menuArguments.document.elementFromPoint(objEvent.clientX, objEvent.clientY)
>         if objEvent.type = "MenuExtAnchor" then 
>                 set objSrcAnchor = objEventElement
>                 do until TypeName(objSrcAnchor) = "HTMLAnchorElement"
>                         set objSrcAnchor = objSrcAnchor.parentElement
>                 loop
>                 SetURL objSrcAnchor.href
>         elseif objEvent.type = "MenuExtImage" then
>                 if TypeName(objEventElement) = "HTMLAreaElement" Then
>                         SetURL objEventElement.href
>                 else 
>                         set objSrcImage = objEventElement
>                         set objSrcAnchor = objSrcImage.parentElement
>                         do until TypeName(objSrcAnchor) = "HTMLAnchorElement"
>                                 set objSrcAnchor = objSrcAnchor.parentElement
>                                 if TypeName(objSrcAnchor) = "Nothing" Then 
>                                         SetURL objSrcImage.href
>                                         exit Sub
>                                 end if
>                         loop
>                         SetURL objSrcAnchor.href
>                 end if
>         elseIf objEvent.type = "MenuExtUnknown" Then
>                 set objSrcAnchor = objEventElement
>                 do until TypeName(objSrcAnchor) = "HTMLAnchorElement"
>                         set objSrcAnchor = objSrcAnchor.parentElement
>                         if TypeName(objSrcAnchor) = "Nothing" Then 
>                                 SetURL objEventElement.href
>                                 exit Sub
>                         end If
>                 loop
>                 SetURL objSrcAnchor.href
>         end If
> end sub
> Call OnIEMenuExt()
> </SCRIPT>

元URA気彫り

参考：2000/04/03(月)23時45分54秒